home *** CD-ROM | disk | FTP | other *** search
/ Languguage OS 2 / Languguage OS II Version 10-94 (Knowledge Media)(1994).ISO / gnu / glibc108.zip / glibc108 / sysdeps / mach / hurd / errlist.awk < prev    next >
Text File  |  1994-02-03  |  2KB  |  64 lines
  1. # Copyright (C) 1991, 1992, 1993, 1994 Free Software Foundation, Inc.
  2. # This file is part of the GNU C Library.
  3.  
  4. # The GNU C Library is free software; you can redistribute it and/or
  5. # modify it under the terms of the GNU Library General Public License
  6. # as published by the Free Software Foundation; either version 2 of
  7. # the License, or (at your option) any later version.
  8.  
  9. # The GNU C Library is distributed in the hope that it will be useful,
  10. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12. # Library General Public License for more details.
  13.  
  14. # You should have received a copy of the GNU Library General Public
  15. # License along with the GNU C Library; see the file COPYING.LIB.  If
  16. # not, write to the Free Software Foundation, Inc., 675 Mass Ave,
  17. # Cambridge, MA 02139, USA.
  18.  
  19. # errno.texinfo contains lines like:
  20. # @comment errno.h
  21. # @comment POSIX.1: Function not implemented
  22. # @deftypevr Macro int ENOSYS
  23.  
  24. BEGIN {
  25.     print "/* This file is generated from errno.texi by errlist.awk.  */"
  26.     print "";
  27.     print "#ifndef HAVE_GNU_LD"
  28.     print "#define _sys_nerr sys_nerr"
  29.     print "#define _sys_errlist sys_errlist"
  30.     print "#endif"
  31.     print ""
  32.     print "const char *_sys_errlist[] =";
  33.     print "  {";
  34.     errno = 0;
  35.     print "    \"Success\","
  36.   }
  37. $1 == "@comment" && $2 == "errno.h" { errnoh=1; next }
  38. errnoh == 1 && $1 == "@comment" \
  39.   {
  40.     ++errnoh;
  41.     etext = $3;
  42.     for (i = 4; i <= NF; ++i)
  43.       etext = etext " " $i;
  44.     next;
  45.   }
  46. errnoh == 2 && $1 == "@deftypevr"  && $2 == "Macro" && $3 == "int" \
  47.   {
  48.     e = $4;
  49.     if (e != "EAGAIN")
  50.       printf "%-40s/* %d = %s */\n", "    \"" etext "\",", ++errno, e;
  51.     next;
  52.   }
  53. { errnoh=0 }
  54. END {
  55.   print "  };";
  56.   print "";
  57.   print "#include <errno.h>";
  58.   ++errno;
  59.   printf "#if _HURD_ERRNOS != %d\n", errno;
  60.   print "#error errlist/errnos generation bug";
  61.   print "#endif"
  62.   printf "const int _sys_nerr = %d;\n", errno;
  63.   }
  64.